
      DOUBLE PRECISION FUNCTION SUSWD1(N,E12)
C --------------------------------------------------------------------------
C     Calculate differential decay probability dL/dE1dE2 for
C     Photino -> nu 2j
C
C eg
C        Photino         q   
C     ------->---------------------
C                    \
C                     \  sqbar                     
C                      \      
C                       \------------ (anti)nu
C                        \
C                         \ qbar
C                          \
C
C     Author: JMB Last change 20/2/92
C --------------------------------------------------------------------------
C
      IMPLICIT NONE
C
      INCLUDE 'SUSANA.INC'
C
      INTEGER N
      DOUBLE PRECISION E12(2), Eye, Eyd, ddu, edd, pdu, pdd, pde
      DOUBLE PRECISION edu, Du, Dd, De, dPS, costh, mx2, temp
C
      Eye = E12(1)
      Eyd = E12(2)
C
      IF (msus(8)-Eye-Eyd-SQRT(mdd2).LE.0.0) THEN
        SUSWD1 = 0.0
        GOTO 8900
      ENDIF
      IF ( msin2 .GE. Eyd**2 ) THEN
        SUSWD1 = 0.0
        GOTO 8900
      ENDIF
      IF ( Eye**2 .LE. 0.0 ) THEN
        SUSWD1 = 0.0
        GOTO 8900
      ENDIF
C
      temp  = 1. + (mp2 - 2.*msus(8)*(Eye + Eyd))/(2.*Eye*Eyd)
      costh = temp /  SQRT(1.- msin2/Eyd**2)
      IF (ABS(costh).GT.1.) THEN
        SUSWD1 = 0.0
        GOTO 8900
      ENDIF
C
C -   4-vector products (p = photino)
      pde = msus(8)*Eye
      pdd = msus(8)*Eyd
      pdu = mp2 - msus(8)*(Eyd+Eye)
      edd = Eye*Eyd*(1. - temp )
      edu = msus(8)*Eye - edd
      ddu = pdd - edd - msin2
      Dd  = mp2 - msus(ssq)**2 - 2.*pdd - msin2
      Du  = mp2 - msus(dsq1)**2 - 2.*pdd - mdd2
C
C -   Matrix element squared.
      mx2 = 8.*e2*lambda**2*( ed**2*pdu*edd/Du**2
     & + ed**2*pdd*edu/Dd**2 
     & + ed*ed*(edu*pdd-ddu*pde+pdu*edd)/(Du*Dd) )
C
C -   Phase space.
      dPS = 1./(32.* pi**3 * SQRT(1-msin2/Eyd**2))
C
C -   And the final width, dGAMMA;
      SUSWD1 = mx2*dPS/(2.*msus(8))
C
 8900 CONTINUE
C
      RETURN
      END
