
      DOUBLE PRECISION FUNCTION SUSWD2(N,E12)
C --------------------------------------------------------------------------
C     Calculate differential decay probability dL/dE1dE2 for
C     Photino -> l 2j
C
C     eg
C        Photino            e+
C     ------->---------------------
C                    \
C                     \  se-                     
C                      \      
C                       \------------ q
C                        \
C                         \ q'
C                          \
C
C     Author: JMB Last change 17/2/92
C ---------------------------------------------------------------------------
C
      IMPLICIT NONE
C
      INCLUDE 'SUSANA.INC'
C
      INTEGER N
      REAL a, b, c, ulmass
      DOUBLE PRECISION E12(2), Eye, Eyd, ddu, edd, pdu, pdd, pde
      DOUBLE PRECISION edu, Du, Dd, De, dPS, costh, mx2, temp
C
      Eye = E12(1)
      Eyd = E12(2)
C
      IF (msus(8)-Eye-Eyd-SQRT(mdu2).LE.0.0) THEN
        SUSWD2 = 0.0
        GOTO 8900
      ENDIF
      IF ( msin2 .GE. Eyd**2 ) THEN
        SUSWD2 = 0.0
        GOTO 8900
      ENDIF
      IF ( ulmass(11) .GE. Eye**2 ) THEN
        SUSWD2 = 0.0
        GOTO 8900
      ENDIF
C
      temp = 1. + (mp2 + msin2 - 2.*msus(8)*(Eye + Eyd) - mdu2) 
     &         /(2.*Eye*Eyd) 
      costh = temp / SQRT(1.- msin2/Eyd**2)
      IF (ABS(costh).GT.1.) THEN
        SUSWD2 = 0.0
        GOTO 8900
      ENDIF
C
C -   4-vector products (p = photino)
      pde = msus(8)*Eye
      pdd = msus(8)*Eyd
      pdu = mp2 - msus(8)*(Eyd+Eye)
      edd = Eye*Eyd*(1. - temp )
      edu = msus(8)*Eye - edd
      ddu = pdd - edd - msin2
      De  = mp2 - msus(7)**2 - 2.*pde
      Dd  = mp2 - msus(ssq)**2 - 2.*pdd + msin2
      Du  = mp2 - msus(dsq2)**2 - 2.*pdu + mdu2
C
C -   Matrix element squared.
      mx2 = 8.*e2*lambda**2*(ee**2*pde*ddu/De**2 + eu**2*pdu*edd/Du**2
     & + ed**2*pdd*edu/Dd**2 - ee*eu*(pde*ddu-pdd*edu+pdu*edd)/(De*Du)
     & + ed*ee*(edu*pdd-pdu*edd+ddu*pde)/(De*Dd) 
     & + eu*ed*(edu*pdd-ddu*pde+pdu*edd)/(Du*Dd) )
C
C -   Phase space.
      dPS = 1./(32.* pi**3 * SQRT(1-msin2/Eyd**2))
C
C -   And the final width, dGAMMA;
      SUSWD2 = mx2*dPS/(2.*msus(8))
C
 8900 CONTINUE
C
      RETURN
      END
